Как "отловить" нажатие кнопки Отмена или Закрыть [X], при использовании функции InputBox?

Если при вызове функции InputBox, Вам необходимо отследить нажатия кнопок в диалоговом окне, т.е. определить, была ли нажата кнопка ОК в т.ч. и с пустым полем, или пользователь действительно кликнул кнопку Отмена или Закрыть [X], то:

1. Вариант
   code: #vba

   Dim iResult As String
    
   iResult = InputBox( _
   Prompt:="Введите необходимый текст", Title:="Моя программа")
    
   If VBA.StrPtr(iResult) <> 0 Then
      MsgBox "Пользователь нажал кнопку Ok", , ""
   Else
      MsgBox "Пользователь нажал кнопку Отмена/Закрыть", , ""
   End If

   Если же Вас интересует состояние текстового поля, проще говоря, заполнен или нет Edit, то:

   code: #vba

   Dim iResult As String
    
   iResult = InputBox( _
   Prompt:="Введите необходимый текст", Title:="Моя программа")
    
   If VBA.StrPtr(iResult) = 0 Then
      MsgBox "Пользователь нажал кнопку Отмена/Закрыть"
   Else
      If iResult = "" Then 'If Len(iResult) = 0 Then
         MsgBox "Пользователь ничего не ввёл, однако нажал кнопку Ok"
      Else
         MsgBox "Нажали кнопку Ok , предварительно заполнив : " & iResult
      End If
   End If

2. Вариант.

   Решить поставленную задачу также можно с помощью метода .InputBox объекта Application

   code: #vba

   Dim iResult 'As Variant
   
   iResult = Application.InputBox(Type:=2, _
   Prompt:="Введите необходимый текст", Title:="Моя программа")
    
   If iResult = False Then
      MsgBox "Пользователь нажал кнопку Отмена/Закрыть"
   Else
      If iResult = "" Then 'If Len(iResult) = 0
         MsgBox "Пользователь ничего не ввёл и нажал кнопку Ok"
      Else
         MsgBox "Пользователь ввёл : " & iResult
      End If
   End If

   code: #vba

   Dim iResult As Variant
    
   iResult = Application.InputBox(Type:=2, _
   Prompt:="Введите необходимый текст", Title:="Моя программа")
    
   Select Case iResult
       Case False
          MsgBox "Пользователь нажал кнопку Отмена/Закрыть"
       Case ""
          MsgBox "Пользователь ничего не ввёл и нажал кнопку Ok"
       Case Else
          MsgBox "Пользователь ввёл : " & iResult
   End Select

   Поделиться:

   Похожие статьи:

   теги: excel, vba, макросы, нажатие кнопки, функция inputbox